%option 8bit nodefault


%{

#include <stdio.h>
#include <ctype.h>
#include <string.h>
#include <stdlib.h>
#include "g2m.h"

%}


nl		(\r\n|\r|\n)
ws		[ \t\r\n]+
open		"<"
close		">"
namestart	[A-Za-z\200-\377_]
namechar	[A-Za-z\200-\377_0-9.-:]
name		{namestart}{namechar}*
comment		{open}"!--"([^-]|"-"[^-])*"--"{close}
string		\"([^"])*\"|\'([^'])*\'
data		{string}|[^<]+
whatever	{string}|{name}

/*
 * The CONTENT mode is used for the content of elements, i.e.,
 * between the ">" and "<" of element tags.
 * The INITIAL mode is used outside the top level element
 * and inside markup.
 */

%s CONTENT


%%

<INITIAL>{ws}		{yylval.s=strdup(yytext); return WS;}
<INITIAL>"/"		{return SLASH;}
<INITIAL>"="		{return EQ;}
<INITIAL>{close}	{BEGIN(CONTENT); return CLOSE;}
<INITIAL>{whatever}	{yylval.s = strdup(yytext); return NAME;}

{open}{name}		{BEGIN(INITIAL); yylval.s=strdup(&yytext[1]); return START;}
{open}"!"{name}		{BEGIN(INITIAL); yylval.s=strdup(&yytext[2]); return STARTHDR;}
{open}"/"		{BEGIN(INITIAL); return END;}
{comment}		{yylval.s = strdup(yytext); return COMMENT;}

<CONTENT>{data}		{yylval.s = strdup(yytext); return DATA;}

.			{fprintf(stderr, "!ERROR(%c)\n", *yytext);}